/***********************************************************************/

/* 1. LEONAR.SAS: Ueberpruefung der Leonardo-Regel.
   Die Datendatei muss mit Grogra-Analyseoption F erzeugt worden sein. */

filename ein 'c:\gg\ei1_f.dat';
data f1;
   infile ein;
   input sname $ l d ord age at ats atm atb sdq sd z rx ry rz;
   if at le 1 then delete;
   if d = 1.01 then delete;
   dq = d * d;
run;
proc sort;
   by sdq;
run;
proc reg simple;
   model dq = sdq;
   /* restrict intercep = 0; */
   output out = p p=p r=r;
run;
goptions reset = all;
filename pfile 'ei1_f.eps';
/* goptions device = ps
   gsfmode = replace
   gsfname = pfile;  */
symbol1 i=none v=star c=black;
symbol2 i=join v=none c=red;
axis1 label = ('Summe der Durchmesserquadrate (Tochtersegm.)');
axis2 label = ('Durch-' j=r 'messer-' j=r 'quadrat');
    /*  order = (0 to 4000 by 500);  */
proc gplot;
   plot dq * sdq = 1 p * sdq = 2 / overlay
   haxis = axis1
   vaxis = axis2;
   title 'Leonardo';
run;


/**************************************************************************/

/* 2. AKROTON.SAS: Messung der akrotonen Tendenz der Trieblaenge.
   Die Datendatei muss mit Grogra-Analyseoption G erzeugt worden sein.
   Als Cluster-Distanz (von Grogra erfragt) kann man z.B. 5 mm verwenden. */

filename ein 'c:\gg\ei1_gv.dat';
data akro;
   infile ein;
   input sprname $ mname $ ord age pcl q ql w l acl lb lc lm iz izm izb;
   if pcl = 0 then delete;  /* verlaengernder Spross */
   if lb <= 0 then delete;  /* big brother is too small */
   if l <= 0 then delete;   /* shoot itself is too small */
   if iz <= -1 then delete; /* Marker fuer Blatt oder Frucht */
   lv = l / lb;
   /* if lv >= 2 then delete;
   if lv <= 0.2 then delete;  */
   pos = 1.0 - q;   /* q ist die relative Position, v.d.Spitze gerechnet */
run;
filename plotfile 'akroton.eps';
/* goptions device = ps
   gsfmode = replace
   gsfname = plotfile;   */
goptions htext = 5.5 pct;
proc sort data = akro;
   by pos;
run;
proc means data = akro;
   var lv pos;
run;
proc reg data = akro simple;
   model lv = pos;
   output out = p p = p r = r;
run;
symbol1 i=none v=star c=black;
symbol2 i=join v=none c=black;
axis1 label=('relative position at the mother gu (apex = 1)');
axis2 label=('length' j=r 'ratio' j=r 'u/w');
proc gplot;
   plot lv * pos = 1
         p * pos = 2
      /overlay haxis = axis1 vaxis = axis2;
   title ' ';
   label lv = ' ' pos = ' ';
run;

/*************************************************************************/

/* 3. ACHTREND.SAS: Messung des Achsentrends (Laengenfaktor fuer
   aufeinanderfolgende Triebe derselben Achse), klassiert nach
   Verzweigungsordnung.
   Die Datendatei muss mit Grogra-Analyseoption G erzeugt worden sein.  */

filename ein 'c:\gg\ei1_gv.dat';
data atrend;
   infile ein;
   input sprname $ mname $ ord age pcl q ql w l acl lb lc lm iz izm izb;
   if pcl NE 0 then delete; /* Seitenspross */
   if l <= 0 then delete;   /* Spross ist zu kurz */
   if lm <= 0 then delete;  /* Mutterspross ist zu kurz */
   kennung = substr(sprname, 1, 1);
   if kennung = 'b' then delete;   /* Marker fuer Blatt */
   if l = 7.07 then delete;  /* default-Laenge fuer nicht gemessene Spr. */
   if lm = 7.07 then delete; /* dito */
   lv = l / lm;
   /* if lv >= 2 then delete;
   if lv <= 0.2 then delete;  */
run;
filename plotfile 'achtrend.eps';
/* goptions device = ps
   gsfmode = replace
   gsfname = plotfile;   */
goptions htext = 5.5 pct;
proc sort data = atrend;
   by lm;
run;
title 'Achsentrend';
proc means data = atrend;
   var lv;
   class ord;
run;
proc means data = atrend;
   var lv;
run;

Zurück zur Veranstaltungs-Seite

Zur Seite der Arbeitsgruppe Pflanzenmodellierung