/* mspruce.ssy: 3 distance-sensitive spruce trees with different colours */

\const nbx 3,
\const nby 1,
\const dis 200,
\const ang0 50,
\var p0 uniform 0.85 1.,
\var p1 uniform 0.2 0.85,
\var ro uniform 0 360,
\var eps0 normal 0 5,
\var eps1 normal 0 10,
\var eps2 normal 0 30,
\var a table 0 15 25 32 37 40,
\var ai0 table 0 0 0 4,
\var ai1 table 0 0 0 2 4 8,
\var incr table 1.3 0.8,
\var k index,
\var bl normal 100 30,
\var len length,
\var n distribution 0 0 0 0 0 0.1 0.4 0.3 0.2,
\var fdist function 2 1,
* # RL90 &(nbx) < [ &(nby) < [ RL-90 L(bl) P(10+k) D2 bud(0,0) ] f(dis) > ]
    RU90 f(dis) RU-90 >,
(o=0) bud(o,p) # gu(2.0,0) RH(ro)
    &(n) < [ @(p0) RH(k*360/n_+eps1) RL(ang0+eps0) an(1) L*0.65 bud(1,0) ] > 
    RH(ro)
    &(3) < [ @(p1) RH(k*120   +eps2) RL(ang0+eps0) an(1) L*0.4  bud(1,1) ] > 
    bud(o,p),
(fdist(10) > 30 && (o=1 || o=2)) bud(o,p) # gu(incr(p),0) 
    [ @(p0) RH15  RU(45+eps0) $ L*0.7 bud(o+1,p) ]
    [ @(p0) RH-15 RU(-45+eps0) $ L*0.7 bud(o+1,p) ] bn(1,p) bud(o,p),
(fdist(10) > 30 && o=3) bud(o,p) # gu(incr(p),0) L*0.7 bud(4,p),
gu(delta,t) # gu(delta,t+1),
an(t) # an(t+1),
bn(t,p) # bn(t+1,p),
bud(o,p) ## P4 F3,
an(t) ## RL(a(t)),
(p=0) bn(t,p) ## RL(ai0(t)),
(p=1) bn(t,p) ## RL(ai1(t)),
gu(delta,t) ## Dl+(delta*t) Nl(80*len) Ul(len) F

Zurück zur Veranstaltungs-Seite

Zur Seite der Arbeitsgruppe Pflanzenmodellierung